[manjaro-dev] [pamac] 0.9.7

[Guillaume Benoit]

Pamac 0.9.7 is out !

What's new:
- add a config file at /etc/pamac.conf, settings supported:
      - enable/disable AUR support
      - pamac-tray refresh period
      - remove unrequired deps (recurse option: -Rs)
- this settings can be changed via pamac-manager/updater GUI
- add a "view history" entry in pamac-manager menu
- add AUR support to pamac-install script (if enabled in pamac.conf)

Guillaume
-------------- next part --------------
# Maintainer: Guillaume Benoit <guillaume at manjaro.org>

pkgname=pamac
pkgver=0.9.7
pkgrel=1
pkgdesc="A gtk3 frontend for pyalpm"
arch=(any)
url="https://git.manjaro.org/core/pamac"
license=('GPL')
depends=('python>=3.3' 'python<3.4' 'pacman>=4.1' 'pyalpm=0.6.2.2' 'gtk3>=3.6' 'python-requests' 'python-gobject' 'python-dbus' 'dbus-glib' 'libnotify' 'namcap')
optdepends=('polkit-gnome: needed for authentification in Cinnamon, Gnome' 'lxpolkit: needed for authentification in Xfce, LXDE etc.')
makedepends=('gettext' 'itstool' 'git')
conflicts=('pamac-aur')
replaces=('pamac-aur')
options=(!emptydirs)
install=$pkgname-install
_git=No
_snapshot=62991a730486da90fea53573adc06e2d381a9219

if [ "$_git" == "Yes" ]; then
   source=(git+http://git.manjaro.org/core/pamac.git)
   sha256sums=('SKIP')
else
   source=("pamac-$pkgver.tar.gz::http://git.manjaro.org/core/pamac/repository/archive?ref=v$pkgver")
   sha256sums=('32067c3af796f2a86be3a6a2c3dc3d53384583afb4a4568441804043bfa02ec4')
   #source=("pamac-$pkgver-$pkgrel.tar.gz::http://git.manjaro.org/core/pamac/repository/archive?ref=$_snapshot")
   #sha256sums=('1dfa19f1cd1787f7126dccc493a62036a8a2b5aaae4995e4272d5b2fb360da95')
fi

package() {
  if [ -e "$srcdir/core-$pkgname" ]; then
	   cd "$srcdir/core-$pkgname"
  fi
  if [ -e "$srcdir/$pkgname" ]; then
     cd "$srcdir/$pkgname"
  fi
  if [ -e "$srcdir/$pkgname.git" ]; then
	   cd "$srcdir/$pkgname.git"
  fi

	# match version with pkgver
	sed -i -e "s|^.*version =.*|version = \'$pkgver\'|" pamac-manager.py

	python setup.py install --root="$pkgdir/" --optimize=1
	mkdir -p "${pkgdir}/usr/share/pamac"
	cp -r "gui" "${pkgdir}/usr/share/pamac"
	cp -r "data/icons" "${pkgdir}/usr/share/pamac"
	mkdir -p "${pkgdir}/usr/share/applications"
	cp "data/applications/pamac-install.desktop" "${pkgdir}/usr/share/applications"
	cp "data/applications/pamac-manager.desktop" "${pkgdir}/usr/share/applications"
	cp "data/applications/pamac-updater.desktop" "${pkgdir}/usr/share/applications"
	mkdir -p "${pkgdir}/etc/xdg/autostart"
	cp "data/applications/pamac-tray.desktop" "${pkgdir}/etc/xdg/autostart"
	cp "data/config/pamac.conf" "${pkgdir}/etc"
	install -Dm744 "pamac-daemon.py" "${pkgdir}/usr/bin/pamac-daemon"
	install -Dm755 "pamac-manager.py" "${pkgdir}/usr/bin/pamac-manager"
	install -Dm755 "pamac-updater.py" "${pkgdir}/usr/bin/pamac-updater"
	install -Dm755 "pamac-tray.py" "${pkgdir}/usr/bin/pamac-tray"
	install -Dm755 "pamac-refresh.py" "${pkgdir}/usr/bin/pamac-refresh"
	install -Dm755 "pamac-install.py" "${pkgdir}/usr/bin/pamac-install"
	install -Dm755 "pamac-check_updates.py" "${pkgdir}/usr/bin/pamac-check_updates"
	install -Dm644 "data/dbus/org.manjaro.pamac.conf" "${pkgdir}/etc/dbus-1/system.d/org.manjaro.pamac.conf"
	install -Dm644 "data/dbus/org.manjaro.pamac.service" "${pkgdir}/usr/share/dbus-1/system-services/org.manjaro.pamac.service"
	install -Dm644 "data/systemd/pamac.service" "${pkgdir}/usr/lib/systemd/system/pamac.service"
	install -Dm744 "data/networkmanager/99_update_pamac_tray" "${pkgdir}/etc/NetworkManager/dispatcher.d/99_update_pamac_tray"
	# create .mo translation files
	mkdir -p mo
	for i in `ls po | sed s'|.po||'` ; do
		msgfmt -c "po/$i.po" -o "mo/$i.mo"
	done
	# add translation in policy file
	itstool -j "data/polkit/org.manjaro.pamac.policy" -o "data/polkit/org.manjaro.pamac.policy.out" `ls mo/*`
	# rename mo files only here else istool failed
	for i in `ls mo | sed s'|.mo||'` ; do
		mkdir -p "${pkgdir}/usr/share/locale/$i/LC_MESSAGES/"
		mv "mo/$i.mo" "${pkgdir}/usr/share/locale/$i/LC_MESSAGES/pamac.mo"
	done
	install -Dm644 "data/polkit/org.manjaro.pamac.policy.out" "${pkgdir}/usr/share/polkit-1/actions/org.manjaro.pamac.policy"

}

# vim:set ts=2 sw=2 et:
-------------- next part --------------
A non-text attachment was scrubbed...
Name: pamac-0.9.7-1-any.pkg.tar.xz
Type: application/x-xz
Size: 129880 bytes
Desc: not available
URL: <http://lists.manjaro.org/pipermail/manjaro-dev/attachments/20140201/19b3bf4e/attachment-0001.bin>
-------------- next part --------------
A non-text attachment was scrubbed...
Name: pamac-0.9.7-1-any.pkg.tar.xz.sig
Type: application/pgp-signature
Size: 287 bytes
Desc: not available
URL: <http://lists.manjaro.org/pipermail/manjaro-dev/attachments/20140201/19b3bf4e/attachment-0001.sig>